#!/bin/bash

if ! which gnuplot > /dev/null 2>&1
then
    echo 'gnuplot not found - skipping graph creation' >&2
    exit 1
fi

gnuplot<<EOF
    set grid

    set term pngcairo size 800,600
    set style line 1  lt 2 lw 1 lc "green"
    set style line 11 lt 2 lw 2 lc "green" dt 2
    set style line 2  lt 2 lw 1 lc "red"
    set style line 22 lt 2 lw 2 lc "red" dt 2
    set style line 3  lt 2 lw 1 lc "black"
    set style line 33 lt 2 lw 2 lc "black" dt 2

    LIST =      system('ls -1 ../postProcessing/graph/ | sort -g')
    NUM =       words(LIST)
    TIMES(n) =  word(LIST,n)

    FILE(n)="../postProcessing/graph/".TIMES(n)."/line.csv"

    set xlabel 'x'
    set ylabel '{/Symbol a}_{air}'

    set yrange [0:1.05]

    set output 'alphaControl.png'
    CONTROL = "reference/postProcessing/graph/line.csv"
    PRESENT = FILE(NUM)
    plot CONTROL u 1:(column('alpha.air1')) w l ls 11 t 'air1 (control)', \
         CONTROL u 1:(column('alpha.air2')) w l ls 22 t 'air2 (control)', \
         PRESENT u 1:(column('alpha.air1')) w l ls 1 t 'air1', \
         PRESENT u 1:(column('alpha.air2')) w l ls 2 t 'air2', \
         PRESENT u 1:(column('alpha.air1')+column('alpha.air2')+column('alpha.water')) w l ls 3 t 'air1+air2+water'

    set output 'alphaNoFiltering.png'
    NOFILTERING = "noFiltering/line.csv"
    PRESENT = FILE(NUM)
    plot NOFILTERING u 1:(column('alpha.air1')) w l ls 11 t 'air1 (unfiltered)', \
         NOFILTERING u 1:(column('alpha.air2')) w l ls 22 t 'air2 (unfiltered)', \
         NOFILTERING u 1:(column('alpha.air1')+column('alpha.air2')+column('alpha.water')) w l ls 33 t 'air1+air2+water (unfiltered)', \
         PRESENT u 1:(column('alpha.air1')) w l ls 1 t 'air1', \
         PRESENT u 1:(column('alpha.air2')) w l ls 2 t 'air2', \
         PRESENT u 1:(column('alpha.air1')+column('alpha.air2')+column('alpha.water')) w l ls 3 t 'air1+air2+water'
EOF

#------------------------------------------------------------------------------
