#!/bin/bash

if ! which gnuplot > /dev/null 2>&1
then
    echo 'gnuplot not found - skipping graph creation' >&2
    exit 1
fi

gnuplot<<EOF
    set terminal pngcairo
    set output '../numberDensity.png'
    set decimalsign '.'

    set format xy '%g'
    set xtics 1e1 mirror
    set xlabel 'v(m^{3})'
    set ytics 1e1 mirror
    set ylabel 'n(m^{-3}m^{-3})'

    set logscale xy
    set xrange [1e-5:1.5]
    set yrange [1e-5:10]
    set key bottom left

    N0 = 0.05
    v0 = 1.0

    n(x,t) = N0*exp(-t*x**2.0)*2.0*t*v0

    numberDensityBubbles = '../postProcessing/numberDensity.bubbles/10/numberDensity.bubbles.xy'
    numberDensityDroplets = '../postProcessing/numberDensity.droplets/10/numberDensity.droplets.xy'

    plot '<printf "1 0.05\n1 1e-5\n"' w l lc rgb 'black' t 'Init. Cond.',\
    n(x,10.0) dt 2 lc rgb 'black' t 'Ziff and McGrady (1985)',\
    'numberDensity.bubbles.xy' every ::0::19 u 1:2 w p pt 1 lc rgb 'red' lw 3 t 'air1 Ref.',\
    numberDensityBubbles every ::0::19 u 1:2 w p pt 1 lc rgb 'black' t 'air1',\
    'numberDensity.bubbles.xy' every ::20::24 u 1:2 w p pt 5 lc rgb 'red' lw 3 t 'air2 Ref.',\
    numberDensityBubbles every ::20::24 u 1:2 w p pt 5 lc rgb 'black' t 'air2',\
    'numberDensity.bubbles.xy' every ::25::28 u 1:2 w p pt 9 lc rgb 'red' lw 3 t 'air3 Ref.',\
    numberDensityDroplets every ::25::28 u 1:2 w p pt 9 lc rgb 'black' t 'air3',\
    'numberDensity.droplets.xy' every ::0::19 u 1:2 w p pt 1 lc rgb 'red' lw 3 t 'water1 Ref.',\
    numberDensityDroplets every ::0::19 u 1:2 w p pt 1 lc rgb 'black' t 'water1',\
    'numberDensity.droplets.xy' every ::20::24 u 1:2 w p pt 5 lc rgb 'red' lw 3 t 'water2 Ref.',\
    numberDensityDroplets every ::20::24 u 1:2 w p pt 5 lc rgb 'black' t 'water2',\
    'numberDensity.droplets.xy' every ::25::28 u 1:2 w p pt 9 lc rgb 'red' lw 3 t 'water3 Ref.',\
    numberDensityDroplets every ::25::28 u 1:2 w p pt 9 lc rgb 'black' t 'water3'
EOF

#------------------------------------------------------------------------------
