#!/bin/bash

if ! which gnuplot > /dev/null 2>&1
then
    echo 'gnuplot not found - skipping graph creation' >&2
    exit 1
fi

gnuplot<<EOF
    set grid

    #---PNG---
    set term pngcairo size 800,600
    FType = '.png'

    #---graph---
    LIST =      system('ls -1 ../postProcessing/graph/ | sort -g')
    NUM =       words(LIST)
    TIMES(n) =  word(LIST,n)

    FILE(n)="../postProcessing/graph/".TIMES(n)."/line.csv"

    set output 'alphaAir'.FType
    set xlabel 'x'
    set ylabel '{/Symbol a}_{air}'
    plot for [i=1:NUM] FILE(i) u 1:2 w l lw 2      t TIMES(i), \
        'line.csv'             u 1:2 w l lw 2 dt 2 t "reference - 40"

    #---probes---
    PATH='../postProcessing/probes/0/'

    set output 'turbulenceWater'.FType
    set xlabel 't'
    set ylabel 'k_{water}, {/Symbol w}_{water}, {/Symbol n}_{t,water}'
    set logscale y
    set format y '%.0e'
    plot PATH.'k.water'     w l lw 3 t 'k_{water}'          , \
         PATH.'omega.water' w l lw 3 t '{/Symbol w}_{water}', \
         PATH.'nut.water'   w l lw 3 t '{/Symbol n}_{t,water}'

EOF

#------------------------------------------------------------------------------
