#!/bin/bash

if ! which gnuplot > /dev/null 2>&1
then
    echo 'gnuplot not found - skipping graph creation' >&2
    exit 1
fi

gnuplot<<EOF

#------------------------------------------------------------------------------

Td   = 0.1   # domain thickness
Ad   = 1     # domain area
Vd   = Ad*Td # domain volume

#------------------------------------------------------------------------------

set linetype 1 lc rgb "orange" lw 2 dt 1    # oilC
set linetype 2 lc rgb "red"    lw 2 dt 1    # oilD
set linetype 3 lc rgb "blue"   lw 2 dt 1    # water

set grid
set key outside below

FILE  = '../postProcessing/phasesVolume/0/volFieldValue.dat'
RFILE = 'phasesVolume/volFieldValue.dat'

#---PNG---
set term pngcairo size 800,600

set yrange [0:]

#---Volume-Ratio---
set output 'volumeRatio.png'
set title  'Volume Ratio'

set ylabel 'Volume Ratio [-]'

plot RFILE u 1:(\$2/Vd) w l ls 1 dt 2 t 'oilC - reference'  , \
     RFILE u 1:(\$3/Vd) w l ls 2 dt 2 t 'oilD - reference'  , \
     RFILE u 1:(\$4/Vd) w l ls 3 dt 2 t 'water - reference' , \
     FILE  u 1:(\$2/Vd) w l ls 1      t 'oilC'              , \
     FILE  u 1:(\$3/Vd) w l ls 2      t 'oilD'              , \
     FILE  u 1:(\$4/Vd) w l ls 3      t 'water'

EOF

#------------------------------------------------------------------------------
